冰峰雪晴

Read/Update INI configration file function[VBS]

时间：2015-09-19 ┊ 阅读：2,827 次 ┊ 标签: 开发 , 编程 , 经验

'读取ini配置文件里的信息
'参数为ini文件路径，读取的key值
代码如下：

Function GetLastRunSave(strPath,strKeyName)
    Dim FSO, LastRunSave, strReadLine, StrKeyValue
    GetLastRunSave=""
    Set FSO = CreateObject("Scripting.FileSystemObject")
    If Not FSO.FileExists(strPath) Then
        FSO.CreateTextFile(strPath)
        Set LastRunSave = FSO.OpenTextFile(strPath, 2)
        LastRunSave.WriteLine "CheckOpt=NULL"
        LastRunSave.WriteLine "CheckApp=0"
        LastRunSave.Close
    End If
    Set LastRunSave = FSO.OpenTextFile(strPath, 1)
    Do Until LastRunSave.AtEndOfStream
        strReadLine = LastRunSave.ReadLine
        If instr(strReadLine,"=") <> 0 Then
            StrKeyValue = Split(strReadLine,"=")
            If trim(StrKeyValue(0)) = strKeyName Then
                GetLastRunSave = Trim(StrKeyValue(1))
                Exit Do
            End If
        End If
    Loop
    LastRunSave.Close
    Set FSO=Nothing
End Function

'把配置信息写到ini文件里，供程序跑时读取使用
'参数为，ini配置文件路径、key名字、key值
Sub SetLastRunSave(strPath,strKeyName,StrKeyValue)
    Dim FSO, LastRunSave, strReadLine, StrTmpKeyValue, strTmp
    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set LastRunSave = FSO.OpenTextFile(strPath, 1)
    Do Until LastRunSave.AtEndOfStream
        strReadLine = LastRunSave.ReadLine
        If InStr(strReadLine,strKeyName) <> 0 Then
            StrTmpKeyValue = Split(Trim(strReadLine),"=")
            If Trim(StrTmpKeyValue(0)) = strKeyName Then
                strReadLine = strKeyName&"="&StrKeyValue
            End If
        End If
        strTmp = strTmp&strReadLine&vbcrlf
    Loop
    LastRunSave.Close
    Set LastRunSave = FSO.OpenTextFile(strPath, 2)
    LastRunSave.Write Trim(strTmp)
    LastRunSave.Close
    Set FSO=Nothing
End Sub

从百度空间搬回来的文章。

本文固定链接: https://www.amkevin.com/28.html｜冰峰雪晴｜转载请注明出处,谢谢